home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / umich / falcon / programm.ing / nt_dsp1.lzh / NT_DSP1.MSA / FNTNS / SQRT3.ASM < prev    next >
Assembly Source File  |  1989-01-24  |  1KB  |  40 lines
  1. ;
  2. ; This program originally available on the Motorola DSP bulletin board.
  3. ; It is provided under a DISCLAMER OF WARRANTY available from
  4. ; Motorola DSP Operation, 6501 Wm. Cannon Drive W., Austin, Tx., 78735.
  5. ;     
  6. ; Full Precision Square Root by Polynomial Approximation. 
  7. ; 
  8. ; Last Update 09 Feb 87   Version 1.0
  9. ;
  10. sqrt3   macro
  11. sqrt3   ident   1,0
  12. ;
  13. ; SQRT3 Macro
  14. ;
  15. ; Full 23 bit precision square root routine using
  16. ; a successive approximation technique.
  17. ;
  18. ; y  = double precision (48 bit) positive input number
  19. ; b  = 24 bit output root
  20. ;
  21. ; a  = temporary storage
  22. ; x0 = guess
  23. ; x1 = bit being tested
  24. ; y1:y0 = input number
  25.  
  26. sqrt3
  27.         clr     b    #<$40,x0           ; init root and guess
  28.         move                    x0,x1   ; init bit to test
  29.         do      #23,_endl
  30.                                         ;START OF LOOP
  31.         mpy     -x0,x0,a                ; square and negate the guess
  32.         add     y,a                     ; compare to double precision input
  33.         tge     x0,b                    ; update root if input >= guess
  34.         tfr     x1,a                    ; get bit to test
  35.         asr     a                               ; shift to next bit to test
  36.         add     b,a             a,x1            ; form new guess
  37.         move                    a,x0            ; save new guess
  38. _endl                                    ;END OF LOOP
  39.         endm
  40.